VBScript Google Drive: Download a File (Stream to the Filesystem)

Back to Index

Downloads the content of a file by ID. (In this example the file id = 1R_70heIyzIAu1_u0prXbYcaIiJRVkgBl) The file is streamed directly to the filesystem. Note: The alt=media query param must be used to download the file content (as opposed to the file metadata).

Documentation: https://developers.google.com/drive/v3/reference/files/get

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set rest = CreateObject("Chilkat_9_5_0.Rest")

'   Provide a previously obtained OAuth2 access token.
set oauth2 = CreateObject("Chilkat_9_5_0.OAuth2")
oauth2.AccessToken = "OAUTH2_ACCESS_TOKEN"
success = rest.SetAuthOAuth2(oauth2)

success = rest.Connect("www.googleapis.com",443,1,1)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

success = rest.AddQueryParam("includeTeamDriveItems","true")
success = rest.AddQueryParam("supportsTeamDrives","true")
success = rest.AddQueryParam("alt","media")

'  First send the HTTP request.
success = rest.SendReqNoBody("GET","/drive/v3/files/1R_70heIyzIAu1_u0prXbYcaIiJRVkgBl")
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

'  Read the response header.  If the response status code is success, stream to the file.
'  Otherwise receive the error response text.
statusCode = rest.ReadResponseHeader()
If (statusCode < 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

If (statusCode <> 200) Then
    outFile.WriteLine("Received error response code: " & statusCode)
    '  Read the error response body.
    set sbErrResponse = CreateObject("Chilkat_9_5_0.StringBuilder")
    success = rest.ReadRespSb(sbErrResponse)
    If (success <> 1) Then
        outFile.WriteLine(rest.LastErrorText)
        WScript.Quit
    End If

    outFile.WriteLine("Error response:" & sbErrResponse.GetAsString())
    WScript.Quit
End If

'  Stream the response body to the output file.
set respBodyStream = CreateObject("Chilkat_9_5_0.Stream")
respBodyStream.SinkFile = "/someDirectory/penguins.jpg"
success = rest.ReadRespBodyStream(respBodyStream,1)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Example Completed.")

outFile.Close